//----------------------------------------------------------------------
// スクリプト : Town_Geffen v1.0
//----------------------------------------------------------------------

geffen_in.gat,77,167,0	shop	道具商人	68,1750:1,611:40,501:50,502:200,503:550,504:1200,506:40,525:500,601:100,602:500,2241:5000
geffen_in.gat,77,173,0	shop	魔法商人	64,717:600,1601:50,1604:2500,1607:9500,1610:45000,2232:7500,2321:8000,2332:7000
geffen_in.gat,25,177,0	shop	防具商人	66,2101:500,2107:60000,2401:400,2501:1000,2230:50000,2301:10,2303:200,2305:1000,2321:8000,2332:7000
geffen_in.gat,29,177,0	shop	武器商人	47,1750:1,1751:3,1101:100,1701:1000,1201:50,1204:1250,1207:2400,1210:8500,1213:14000,1216:19500,1601:50,1604:2500,1607:9500,1610:45000
geffen_in.gat,74,144,0	shop	商人	66,909:6,911:160,910:40,912:500
geffen_in.gat,171,123,4	shop	道具商人	64,1092:3,1093:10
geffen.gat,193,152,4	shop	テイミング商人	124,537:2500,643:3000,10013:1500,10014:2000

geffen.gat,59,143,0	script	女性	91,{
	mes "[女性]";
	mes "草原で生きるハチのホネットは一生、女王蜂の命令で蜜を集めるの。これがとっても甘くて栄養もたっぷりなので、けっこう高価なものなんですって。";
	next;
	mes "でもね、女王蜂しか食べられないロイヤルゼリーはハチ蜜なんかとは比べられないほど良い物だそうよ。";
	close;
}

geffen.gat,156,190,0	script	青年	82,{
	mes "[青年]";
	mes "魔法に関する研究をしていた時に読んだ、ある古文書の伝説によると、この世界の元になったと言われている<イグドラシル>という木の葉と種、そして実は生きている全ての物の生命に深く関与しているんだそうだ…";
	next;
	mes "まぁ、俺は見たことも、触ったこともないんだけどね。";
	close;
}

geffen_in.gat,164,109,0	script	魔道師	64,{
	mes "[魔道師]";
	mes "魔法の強力な力は因果律によって調節されているのじゃ。";
	next;
	mes "要するに、誰かに害を与えたり、または自然の流れに反する魔法を使った場合、必ずその使用者に反作用が戻ってくるのじゃ。";
	next;
	mes "しかし、その術者の代わりにその反作用を受けてくれる物があれば、安全に魔法が使えるのじゃ。それが<ジェムストーン>と呼ばれる神秘の鉱石なのじゃ。";
	close;
}

geffen.gat,147,26,0	script	青年	97,{
	mes "[青年]";
	mes "この世界のどこかに使用者の精神力を物理的な力に換えて、高い破壊力を発揮する幻想の杖が存在すると聞いたな。";
	next;
	mes "そんな杖があれば、腕力が弱い人でも、精神力だけで大きい力が出せるのか？不思議なことだ。";
	close;
}

geffen.gat,111,48,0	script	女性	101,{
	mes "[女性]";
	mes "ここゲフェンから南の方へ進んだら、大きい森があります。そこにはオークというモンスターが住んでいるそうです。";
	next;
	mes "オークは人間のように独特な文化と言葉を持っていると伝えられているの。";
	close;
}

geffen_in.gat,34,170,0	script	青年	47,{
	mes "[青年]";
	mes "魔法を使っているとき、敵の射程が長い攻撃が邪魔だろう？だから、敵の武器や鎧を傷つけたり、壊したりすることができる武器を考えているんだ。しかしな…あまりうまくいかないんだよな…";
	next;
	mes "何か他のもっといい方法があるんじゃないかなぁ…";
	close;
}

geffen_in.gat,110,172,0	script	クリストファー	63,{
	mes "[クリストファー ギレンロウ]";
	mes "クリストファーの鍛冶屋にようこそ。";
	mes "ここは精錬に関するすべての品物を取り扱っている。";
	mes "さあ…何しに来たんだい？";
	next;
	menu "金敷きの購入",L_MENU_1,"精錬品の購入",L_MENU_2,"金属の購入",L_MENU_3,"原石の精製",L_MENU_4,"やめる",L_MENU_5;
	L_MENU_1:
		mes "[クリストファー ギレンロウ]";
		mes "武器製作に必要な金敷きは硬ければ硬いほどいいものだ。";
		mes "だが、君もすでに知っていると思うが、硬いほど高いわけだ。";
		mes "無理せずに都合がいい物を選ぶんだ。";
		next;
		menu "金敷き - 30,000 Zeny",L_MENU_1A,"オリデオコンの金敷き - 120,000 Zeny",L_MENU_1B,"黄金の金敷き - 300,000 Zeny",L_MENU_1C,"もっと硬い金敷き",L_MENU_1D,"取引をやめる",L_MENU_1E;
		L_MENU_1A:
			if (Zeny < 30000) goto L_MENU_1A_1;
			if (!checkweight(986,1)) goto L_MENU_1A_2;
			set Zeny,Zeny-30000;
			getitem 986,1;
			mes "[クリストファー ギレンロウ]";
			mes "値段も安いし、なかなかいいやつだな。これは。";
			mes "とにかく、ありがとう。また必要なものがあったら、話し掛けてくれ。";
			close;
		L_MENU_1A_1:
			mes "[クリストファー ギレンロウ]";
			mes "君が持っているお金では…無理だな。損する気はないんだ。";
			close;
		L_MENU_1A_2:
			mes "[クリストファー ギレンロウ]";
			mes "重量オーバーです。";
			close;
		L_MENU_1B:
			if (Zeny < 120000) goto L_MENU_1A_1;
			if (!checkweight(987,1)) goto L_MENU_1A_2;
			set Zeny,Zeny-120000;
			getitem 987,1;
			mes "[クリストファー ギレンロウ]";
			mes "やっぱり、目が高いな。鍛冶屋ならこの位の金敷きは必需品だな。";
			mes "とにかく、ありがとう。また必要なものがあったら、話し掛けてくれ。";
			close;
		L_MENU_1C:
			if (Zeny < 300000) goto L_MENU_1A_1;
			if (!checkweight(988,1)) goto L_MENU_1A_2;
			set Zeny,Zeny-300000;
			getitem 988,1;
			mes "[クリストファー ギレンロウ]";
			mes "最高に硬く、美しい金属で作られたこの金敷きを選ぶとは!（感激）";
			mes "これさえあれば、君は立派な鍛冶屋になれる!";
			mes "とにかく、ありがとう。また必要なものがあったら、話し掛けてくれ。";
			close;
		L_MENU_1D:
			mes "[クリストファー ギレンロウ]";
			mes "俺の店に黄金の金敷きより硬いやつは売ってない。";
			mes "伝説の金敷き製作者<リンゲル>が作った物があるとすれば話が違うけど…これ以上硬い金属で作られたものは俺の店だけではなく、どこを探してもないはずだ。";
			close;
		L_MENU_1E:
			mes "[クリストファー ギレンロウ]";
			mes "何か必要なものがあったら話し掛けてな。それじゃ。";
			close;
	L_MENU_2:
		mes "[クリストファー ギレンロウ]";
		mes "立派な鍛冶屋には立派な道具!";
		mes "このクリストファーの鍛冶屋で道具を買うなんて、君は本当にいい鍛冶屋になる将来性がある。";
		mes "好きなやつを選んでくれ。";
		next;
		menu "携帯溶炉 - 150 Zeny",L_MENU_2A,"鋼鉄のハンマー - 1,000 Zeny",L_MENU_2B,"黄金のハンマー- 3,000 Zeny",L_MENU_2C,"オリデオコンのハンマー - 5,000 Zeny",L_MENU_2D,"取引をやめる",L_MENU_2E;
		L_MENU_2A:
			mes "[クリストファー ギレンロウ]";
			mes "金属精製にはこいつだ!";
			next;
			set @BUY_PRICE,150;
			set @BUY_ID,612;
			goto L_SUB_2;
		L_MENU_2B:
			set @BUY_PRICE,1000;
			set @BUY_ID,613;
			goto L_SUB_2;
		L_MENU_2C:
			set @BUY_PRICE,3000;
			set @BUY_ID,614;
			goto L_SUB_2;
		L_MENU_2D:
			set @BUY_PRICE,5000;
			set @BUY_ID,615;
		L_SUB_2:
			mes "[クリストファー ギレンロウ]";
			mes "さあ、どの位買う？";
			mes "いらないのなら０でいいぞ。";
			next;
			input @BUY_NUM;
			if (@BUY_NUM == 0) goto L_MENU_2E;
				set @BUY_ZENY,@BUY_NUM;
				set @BUY_ZENY,@BUY_ZENY*@BUY_PRICE;
				if (Zeny < @BUY_ZENY) goto L_ROOT_2_1;
				if (!checkweight(@BUY_ID,@BUY_NUM)) goto L_ROOT_2_2;
				set Zeny,Zeny-@BUY_ZENY;
				getitem @BUY_ID,@BUY_NUM;
				mes "[クリストファー ギレンロウ]";
				mes "とにかく、ありがとう。また必要なものがあったら、話し掛けてくれ。";
				close;
			L_ROOT_2_1:
				mes "[クリストファー ギレンロウ]";
				mes "君、お金が足りないな…俺も損する訳にはいかないからな…女房がうるさいんだ。";
				close;
			L_ROOT_2_2:
				mes "[クリストファー ギレンロウ]";
				mes "君…顔色悪いな…品物を受け取る前に、荷物を整理した方がいい。";
				close;
		L_MENU_2E:
			mes "[クリストファー ギレンロウ]";
			mes "何か必要なものがあったら話し掛けてな。それじゃ";
			close;
	L_MENU_3:
		mes "[クリストファー ギレンロウ]";
		mes "鉄や鋼鉄の武器を製錬する時に";
		mes "使える金属を売っている。";
		mes "1レベルの武器製錬に使える";
		mes "^007777プラコン^000000 と";
		mes "2レベルの武器製錬に使える";
		mes "^007777エンベルタコン^000000 があるぞ。";
		next;
		menu "プラコン購入",L_MENU_3A,"エンベルタコン購入",L_MENU_3B,"他の金属はないか聞いてみる",L_MENU_3C;
		L_MENU_3A:
	 		mes "[クリストファー ギレンロウ]";
 			mes "プラコンは1個200Zenyだ。";
			set @BUY_PRICE,200;
			set @BUY_ID,1010;
			goto L_SUB_3;
		L_MENU_3B:
	 		mes "エンベルタコンは";
			mes "1個1000Zenyだ。";
			set @BUY_PRICE,1000;
			set @BUY_ID,1011;
		L_SUB_3:
			mes "いらないのなら０でいいぞ。";
 			next;
			input @BUY_NUM;
			if (@BUY_NUM == 0) goto L_MENU_2E;
				set @BUY_ZENY,@BUY_NUM;
				set @BUY_ZENY,@BUY_ZENY*@BUY_PRICE;
				if (Zeny < @BUY_ZENY) goto L_ROOT_2_1;
				if (!checkweight(1010,@BUY_NUM)) goto L_ROOT_2_2;
				set Zeny,Zeny-@BUY_ZENY;
				getitem @BUY_ID,@BUY_NUM;
				mes "[クリストファー ギレンロウ]";
				mes "とにかく、ありがとう。また必要なものがあったら、話し掛けてくれ。";
				close;
		L_MENU_3C:
	 		mes "[クリストファー ギレンロウ]";
 			mes "1レベルと2レベルの武器より";
			mes "レベルが高い武器を精錬するための";
			mes "金属だな。";
			mes "もう知っているかもしれんが､ ";
			mes "オリデオコンとエルニウムは";
	 		mes "手に入れるのがすごく難しくてね…";
 			close;
	L_MENU_4:
		mes "[クリストファー ギレンロウ]";
		mes "精製できる金属はオリデオコンとエルニウムだな。";
		mes "各5つの原石を精製して、純度の高い金属にするんだ。";
		mes "さあ…どの金属にするつもりだい？";
		next;
		menu "オリデオコンを作る",L_MENU_4A,"エルニウムを作る",L_MENU_4B,"やめる",L_MENU_4C;
		L_MENU_4A:
			if (countitem(756)<5) goto L_SUB_4A_1;
			delitem 756,5;
			getitem 984,1;
			mes "[クリストファー ギレンロウ]";
			mes "さあ、オリデオコンだ。また必要ならいつでもどうぞ。";
			close;
		L_SUB_4A_1:
			mes "[クリストファー ギレンロウ]";
			mes "オリデオコン原石が5つなければ、オリデオコンは作れない。";
			close;
		L_MENU_4B:
			if (countitem(757)<5) goto L_SUB_4B_1;
			delitem 757,5;
			getitem 985,1;
			mes "[クリストファー ギレンロウ]";
			mes "さあ、エルニウムだ。また必要ならいつでもどうぞ。";
			close;
		L_SUB_4B_1:
			mes "[クリストファー ギレンロウ]";
			mes "エルニウム原石が5つなければ、エルニウムは作れない。";
			close;
		L_MENU_4C:
			mes "[クリストファー ギレンロウ]";
			mes "何か必要な物があれば、話かけてな。それじゃ、また。";
			close;
	L_MENU_5:
		mes "[クリストファー ギレンロウ]";
		mes "何か必要な物があれば、話かけてな。それじゃ、また。";
		close;
}


