//===== eAthena Script ======================================= 
//= Lighthalzen Airport Staff
//===== By: ================================================== 
//= L0ne_W0lf, Muad_Dib
//===== Current Version: ===================================== 
//= 1.3
//===== Compatible With: ===================================== 
//= eAthena Revision 3000+
//===== Description: ========================================= 
//= Lighthalzen Airport Staff
//===== Additional Comments: ================================= 
//= 1.0 Cloned from einbroch.txt [Justin84]
//= 1.1 Removed Duplicates [Silent]
//= 1.2 Fixed syntax errors for duplicate [KarLaeda]
//= 1.3 Removed use of goto. [L0ne_W0lf]
//============================================================


lhz_airport,126,43,4	script	Airport Staff#1::AirportL	90,{
	mes "[Airport Staff]";
	mes "Welcome to the Airport.";
	mes "How may I help you?";
	next;
	if (select("Board the Airship:Cancel") == 1) {
		mes "[Airport Staff]";
		mes "The Airship boarding fee";
		mes "is 1,200 zeny, but if you've";
		mes "got a Free Ticket for Airship,"; 
		mes "the fee will be waived. Will";
		mes "you board the Airship?";
		next;
		if (select("Yes:No") == 1) {
			if(countitem(7311) > 0) {
				delitem 7311,1;
				warp "lhz_airport",148,51;
				close;
			}
			if(zeny >= 1200) {
				set Zeny,zeny-1200;
				warp "lhz_airport",148,51;
				close;
			}
			mes "[Airport Staff]";
			mes "You don't have enough zeny.";
			close;
		}
	}
	mes "[Airport Staff]";
	mes "Thank you and";
	mes "have a nice day.";
	close;
}

lhz_airport,143,43,4	duplicate(AirportL)	Airport Staff#2	90
lhz_airport,156,43,4	duplicate(AirportL)	Airport Staff#3	90

lhz_airport,126,51,4	script	Airport Staff#4::AirportL2	90,{
	mes "[Airport Staff]";
	mes "Welcome~";
	mes "Please head this";
	mes "way to board the Airship.";
	next;
	if (select("Exit to Main Terminal:Cancel") == 1) {
		mes "[Airport Staff]";
		mes "If you leave the";
		mes "main terminal, you'll";
		mes "have to pay the admission";
		mes "fee again in order to board";
		mes "the Airship. Are you sure";
		mes "that you want to exit?";
		next;
		if (select("Yes:No") == 1) {
			warp "lhz_airport",142,40;
			close;
		}
	}
	mes "[Airport Staff]";
	mes "Alright, thank you";
	mes "for your patronage";
	mes "and I hope you have";
	mes "a pleasant flight~";
	close;
}

lhz_airport,143,51,4	duplicate(AirportL2)	Airport Staff#5	90
lhz_airport,156,51,4	duplicate(AirportL2)	Airport Staff#6	90
