//===== eAthena Script =======================================
//= Prontera Kafras
//===== By: =========================
//= eAthena Dev Team
//===== Current Version: ===================
//= 2.7
//===== Compatible With: =====================
//= eAthena 1.0
//===== Description: ============================================
//= Description of argument settings for callfunc "F_Kafra".
//=  arg(0): When set at 0 the default Kafra message is displayed.
//=    When set to 1 the Niflhiem Kafra message is displayed.
//=    When set to 2 the Guild Kafra message is displayed. 
//=  arg(1): Set to 1 to disable teleport menu option. Otherwise set to 0.
//=  arg(2): Set to 1 to disable info menu.  Otherwise set to 0.
//=  arg(3): Cost of Storage service
//=  arg(4): Cost of Rent a Pushcart service
//===== Additional Comments: ==========================================
//= v1.1 Now using functions :)
//= v2.1b Minor changes to function calls. Using arguments.
//= This version uses arrays .[kobra_k88]
//= 2.2 North Kafra allows you save your position
//= 2.3 New Teleport list, new prices, 2.3a fixed Alberta Teleport [Lupus]
//= 2.3b One Kafra's been moved to Prontera, thx to Vicious_Pucca [Lupus]
//= 2.4 Updated Kafras locations for the mini-map [Lupus]
//= 2.41 New prices [Evera]
//= 2.5 Can't save outside city [Evera]
//= 2.6 Fixed central Kafra position (146,86 -> 146,98) [L0ne_W0lf]
//= 2.7 Updated function calls with new arguments. [L0ne_W0lf]
//=	Added unique Kafra Welcome messages.
//=====================================================================


// North ==================================
prontera,152,326,3	script	Kafra Employee::kaf_prontera	112,{
	cutin "kafra_06",2;
	callfunc "F_KafSetPront";
	mes "[Kafra Employee]";
	mes "Welcome to the";
	mes "Kafra Corporation~";
	mes "The Kafra Services are";
	mes "always here to support";
	mes "you. So how can I be";
	mes "of service today?";
	callfunc "F_Kafra",5,0,0,40,800;

M_Save:
	savepoint "prontera",157,327;
	callfunc "F_KafEnd",0,1,"in the city of Prontera";
}

// SOUTH ======================================
prontera,151,29,0	script	Kafra Employee::kaf_prontera2	115,{
	cutin "kafra_03",2;
	callfunc "F_KafSetPront";
	mes "[Kafra Employee]";
	mes "Welcome~!";
	mes "The Kafra Services";
	mes "are always on your side.";
	mes "So how can I help you?";
	callfunc "F_Kafra",5,0,0,40,800;

	M_Save:
		savepoint "prontera",150,33;
		callfunc "F_KafEnd",0,1,"in the city of Prontera";
}

//WEST=========================================
prontera,29,207,6	script	Kafra Employee::kaf_prontera3	113,{
	cutin "kafra_05",2;
	callfunc "F_KafSetPront";
	mes "[Kafra Employee]";
	mes "The Kafra Corporation";
	mes "is always working to provide";
	mes "you with convenient services.";
	mes "How may I be of assistance?";
	callfunc "F_Kafra",5,0,0,40,800;

	M_Save:
		savepoint "prontera",33,208;
		callfunc "F_KafEnd",0,1,"in the city of Prontera";
}

// East ===========================================
prontera,282,200,2	script	Kafra Employee::kaf_prontera4	114,{
	cutin "kafra_04",2;
	callfunc "F_KafSetPront";
	mes "[Kafra Employee]";
	mes "Welcome!";
	mes "The Kafra Corporation";
	mes "will always support the";
	mes "adventurers of Rune-Midgard";
	mes "with its excellent service. So";
	mes "what can I do for you today?";
	callfunc "F_Kafra",5,0,0,40,800;

	M_Save:
		savepoint "prontera",281,203;
		callfunc "F_KafEnd",0,1,"in the city of Prontera";
}

// Center ===========================================
prontera,146,89,6	script	Kafra Employee::kaf_prontera5	117,{
	cutin "kafra_01",2;
	callfunc "F_KafSetPront";
	mes "[Kafra Employee]";
	mes "Welcome to the";
	mes "Kafra Corporation.";
	mes "The Kafra services";
	mes "are always on your side.";
	mes "How may I assist you?";
	callfunc "F_Kafra",5,0,0,40,800;

M_Save:
	savepoint "prontera",116,73;
	callfunc "F_KafEnd",0,1,"in the city of Prontera";
}


// Function: Sets variables for Prontera Kafras ----------------------------
function	script	F_KafSetPront	{
	cleararray @wrpC$[0],"",getarraysize(@wrpC$);
	setarray @wrpD$[0], "Izlude", "Geffen", "Payon", "Morroc", "Orc Dungeon", "Alberta";
	setarray @wrpP[0], 600, 1200, 1200, 1200, 1200, 1800;
	set @wrpC$[0], @wrpD$[0]+" -> "+@wrpP[0];
	set @wrpC$[1], @wrpD$[1]+" -> "+@wrpP[1];
	set @wrpC$[2], @wrpD$[2]+" -> "+@wrpP[2];
	set @wrpC$[3], @wrpD$[3]+" -> "+@wrpP[3];
	set @wrpC$[4], @wrpD$[4]+" -> "+@wrpP[4];
	set @wrpC$[5], @wrpD$[5]+" -> "+@wrpP[5];
	set @wrpC$[6], "Cancel";
	setarray @viewpX[0], 151, 29, 282, 152;
	setarray @viewpY[0], 29, 207, 200, 326;
	return;
}
