//===== eAthena Script =======================================
//= Morroc Kafras
//===== By: =========================
//= eAthena Dev Team
//===== Current Version: ===================
//= 2.4
//===== Compatible With: =====================
//= eAthena 1.0
//===== Description: ============================================
//= Description of argument settings for callfunc "F_Kafra".
//=  arg(0): When set at 0 the default Kafra message is displayed.
//=    When set to 1 the Niflhiem Kafra message is displayed.
//=    When set to 2 the Guild Kafra message is displayed. 
//=  arg(1): Set to 1 to disable teleport menu option. Otherwise set to 0.
//=  arg(2): Set to 1 to disable info menu.  Otherwise set to 0.
//=  arg(3): Cost of Storage service
//=  arg(4): Cost of Rent a Pushcart service
//===== Additional Comments: ==========================================
//= v1.1 Now using functions :)
//= v2.1b Minor changes to function calls. Using arguments.
//= This version uses arrays .[kobra_k88]
//= 2.2 New teleport destinations, prices [Lupus]
//= 2.3 Can't save outside city [Evera[
//= 2.4 Updated function calls with new arguments. [L0ne_W0lf]
//=	Added unique Kafra Welcome messages.
//=	removed West and East Kafra
//=====================================================================


// South ================================
morocc,156,97,4	script	Kafra Employee::kaf_morocc	113,{
	cutin "kafra_05",2;
	callfunc "F_KafSetMoc";
	mes "[Kafra Employee]";
	mes "The Kafra Corporation";
	mes "is always working to provide";
	mes "you with convenient services.";
	mes "How may I be of assistance?";
	callfunc "F_Kafra",5,0,0,60,930;

	M_Save:
		savepoint "morocc",156,46;
		callfunc "F_KafEnd",0,1,"in the city of Morroc";
}

// North =================================
morocc,160,258,4	script	Kafra::kaf_morocc2	114,{
	cutin "kafra_04",2;
	callfunc "F_KafSetMoc";
	mes "[Kafra Employee]";
	mes "Welcome!";
	mes "The Kafra Corporation";
	mes "will always support the";
	mes "adventurers of Rune-Midgard";
	mes "with its excellent service. So";
	mes "what can I do for you today?";
	callfunc "F_Kafra",5,0,0,60,930;

	M_Save:
		savepoint "morocc",157,272;
		callfunc "F_KafEnd",0,1,"in the city of Morroc";
}

// Function: Sets variables for Morroc Kafras --------------------------------
function	script	F_KafSetMoc	{
	cleararray @wrpC$[0],"",getarraysize(@wrpC$);
	setarray @wrpD$[0], "Prontera", "Payon", "Alberta", "Comodo", "Comodo Pharos Beacon";
	setarray @wrpP[0], 1200, 1200, 1800, 1800, 1200;
	set @wrpC$[0], @wrpD$[0]+" -> "+@wrpP[0];
	set @wrpC$[1], @wrpD$[1]+" -> "+@wrpP[1];
	set @wrpC$[2], @wrpD$[2]+" -> "+@wrpP[2];
	set @wrpC$[3], @wrpD$[3]+" -> "+@wrpP[3];
	set @wrpC$[4], @wrpD$[4]+" -> "+@wrpP[4];
	set @wrpC$[5], "Cancel";
	setarray @viewpX[0], 156, 163, 28, 292;
	setarray @viewpY[0], 97, 260, 167, 211;
	return;
}
